/[eiffelstudio]/branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e
ViewVC logotype

Contents of /branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e

Parent Directory Parent Directory | Revision Log Revision Log


Revision 94868 - (show annotations)
Wed Apr 16 16:20:32 2014 UTC (5 years, 9 months ago) by apaolo
File size: 13807 byte(s)
Added new "Empty rescue clause" Inspector Eiffel rule.
1 note
2 description: "THE Code Analyzer."
3 author: "Stefan Zurfluh"
4 date: "$Date$"
5 revision: "$Revision$"
6
7 class
8 CA_CODE_ANALYZER
9
10 inherit
11 SHARED_EIFFEL_PROJECT
12
13 CA_SHARED_NAMES
14
15 create
16 make
17
18 feature {NONE} -- Initialization
19
20 make
21 -- Initialization for `Current'.
22 do
23 create settings.make
24 create rules.make
25 -- Adding the rules.
26 rules.extend (create {CA_SELF_ASSIGNMENT_RULE}.make)
27 rules.extend (create {CA_UNUSED_ARGUMENT_RULE}.make)
28 rules.extend (create {CA_NPATH_RULE}.make (settings.preference_manager))
29 rules.extend (create {CA_EMPTY_IF_RULE}.make)
30 rules.extend (create {CA_FEATURE_NEVER_CALLED_RULE}.make)
31 rules.extend (create {CA_CQ_SEPARATION_RULE}.make)
32 rules.extend (create {CA_UNNEEDED_OT_LOCAL_RULE}.make)
33 rules.extend (create {CA_UNNEEDED_OBJECT_TEST_RULE}.make) -- Needs type info.
34 rules.extend (create {CA_NESTED_COMPLEXITY_RULE}.make (settings.preference_manager))
35 rules.extend (create {CA_MANY_ARGUMENTS_RULE}.make (settings.preference_manager))
36 rules.extend (create {CA_CREATION_PROC_EXPORTED_RULE}.make)
37 rules.extend (create {CA_VARIABLE_NOT_READ_RULE}.make)
38 rules.extend (create {CA_SEMICOLON_ARGUMENTS_RULE}.make)
39 rules.extend (create {CA_VERY_LONG_ROUTINE_RULE}.make (settings.preference_manager))
40 rules.extend (create {CA_VERY_BIG_CLASS_RULE}.make (settings.preference_manager))
41 rules.extend (create {CA_FEATURE_SECTION_COMMENT_RULE}.make)
42 rules.extend (create {CA_FEATURE_NOT_COMMENTED_RULE}.make)
43 rules.extend (create {CA_BOOLEAN_RESULT_RULE}.make)
44 rules.extend (create {CA_BOOLEAN_COMPARISON_RULE}.make)
45 rules.extend (create {CA_VERY_SHORT_IDENTIFIER_RULE}.make (settings.preference_manager))
46 rules.extend (create {CA_VERY_LONG_IDENTIFIER_RULE}.make (settings.preference_manager))
47 rules.extend (create {CA_MISSING_IS_EQUAL_RULE}.make)
48 rules.extend (create {CA_SIMPLIFIABLE_BOOLEAN_RULE}.make)
49 rules.extend (create {CA_SELF_COMPARISON_RULE}.make)
50 rules.extend (create {CA_TODO_RULE}.make)
51 rules.extend (create {CA_WRONG_LOOP_ITERATION_RULE}.make)
52 rules.extend (create {CA_INSPECT_INSTRUCTIONS_RULE}.make (settings.preference_manager))
53 rules.extend (create {CA_ATTRIBUTE_TO_LOCAL_RULE}.make)
54 rules.extend (create {CA_EMPTY_EFFECTIVE_ROUTINE_RULE}.make)
55 rules.extend (create {CA_IF_ELSE_NOT_EQUAL_RULE}.make)
56 rules.extend (create {CA_SHORT_CIRCUIT_IF_RULE}.make)
57 rules.extend (create {CA_ITERABLE_LOOP_RULE}.make) -- Needs type info.
58 rules.extend (create {CA_COUNT_EQUALS_ZERO_RULE}.make) -- Needs type info.
59 rules.extend (create {CA_DEEPLY_NESTED_IF_RULE}.make (settings.preference_manager))
60 rules.extend (create {CA_UNNEEDED_HELPER_VARIABLE_RULE}.make (settings.preference_manager))
61 rules.extend (create {CA_UNNEEDED_PARENTHESES_RULE}.make)
62 rules.extend (create {CA_CLASS_NAMING_CONVENTION_RULE}.make)
63 rules.extend (create {CA_FEATURE_NAMING_CONVENTION_RULE}.make)
64 rules.extend (create {CA_VARIABLE_NAMING_CONVENTION_RULE}.make)
65 rules.extend (create {CA_ARGUMENT_NAMING_CONVENTION_RULE}.make)
66 rules.extend (create {CA_UNNECESSARY_SIGN_OPERATOR}.make)
67 rules.extend (create {CA_EMPTY_UNCOMMENTED_ROUTINE}.make)
68 rules.extend (create {CA_UNNEEDED_ACCESSOR_FUNCTION}.make)
69 rules.extend (create {CA_MERGEABLE_FEATURE_CLAUSES}.make)
70 rules.extend (create {CA_EMPTY_RESCUE_CLAUSE}.make)
71
72 settings.initialize_rule_settings (rules)
73
74 create classes_to_analyze.make
75 create rule_violations.make (100)
76 create completed_actions
77 create output_actions
78
79 create ignoredby.make (25)
80 create library_class.make (25)
81 create nonlibrary_class.make (25)
82 end
83
84 feature -- Analysis interface
85
86 add_completed_action (a_action: attached PROCEDURE [ANY, TUPLE [ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]]]])
87 -- Adds `a_action' to the list of procedures that will be
88 -- called when analysis has completed.
89 do
90 completed_actions.extend (a_action)
91 end
92
93 add_output_action (a_action: attached PROCEDURE [ANY, TUPLE [READABLE_STRING_GENERAL]])
94 -- Adds `a_action' to the procedures that are called for outputting status. The final results
95 -- (rule violations) are not given to these procedures.
96 do
97 output_actions.extend (a_action)
98 end
99
100 analyze
101 -- Analyze all the classes that have been added.
102 require
103 not is_running
104 local
105 l_rules_checker: CA_ALL_RULES_CHECKER
106 l_task: CA_RULE_CHECKING_TASK
107 l_rules_to_check: LINKED_LIST [CA_RULE]
108 do
109 is_running := True
110
111 create l_rules_checker.make
112 create l_rules_to_check.make
113 across rules as l_rules loop
114 l_rules.item.clear_violations
115 if is_rule_checkable (l_rules.item) then
116 l_rules_to_check.extend (l_rules.item)
117 -- Here we only prepare standard rules. The rule checking task will iterate again
118 -- through the rules and run the analysis on the enabled rules.
119 if attached {CA_STANDARD_RULE} l_rules.item as l_std_rule then
120 l_std_rule.prepare_checking (l_rules_checker)
121 end
122 end
123 end
124
125 create l_task.make (l_rules_checker, l_rules_to_check, classes_to_analyze, agent analysis_completed)
126 l_task.set_output_actions (output_actions)
127 rota.run_task (l_task)
128 end
129
130 is_rule_checkable (a_rule: attached CA_RULE): BOOLEAN
131 -- Will `a_rule' be checked based on the current preferences and based on the current
132 -- checking scope?
133 do
134 Result := a_rule.is_enabled.value
135 and then (system_wide_check or else (not a_rule.is_system_wide))
136 and then is_severity_enabled (a_rule.severity)
137 end
138
139 clear_classes_to_analyze
140 -- Removes all classes that have been added to the list of classes
141 -- to analyze.
142 do
143 classes_to_analyze.wipe_out
144 end
145
146 add_whole_system
147 -- Adds all the classes that are part of the current system. Classes of referenced libraries
148 -- will not be added.
149 local
150 l_cluster: CLUSTER_I
151 do
152 across
153 eiffel_universe.groups as l_groups
154 loop
155 l_cluster ?= l_groups.item
156 -- Only load top-level clusters, as the others will be loaded recursively afterwards.
157 if l_cluster /= Void and then l_cluster.parent_cluster = Void then
158 add_cluster (l_cluster)
159 end
160 end
161
162 system_wide_check := True
163 end
164
165 add_cluster (a_cluster: attached CLUSTER_I)
166 -- Add all classes of cluster `a_cluster'.
167 do
168 system_wide_check := False
169
170 if a_cluster.classes /= Void then
171 across a_cluster.classes as ic loop
172 add_class (ic.item)
173 end
174 end
175
176 if a_cluster.sub_clusters /= Void then
177 across a_cluster.sub_clusters as ic loop
178 add_cluster (ic.item)
179 end
180 end
181 end
182
183 add_group (a_group: attached CONF_GROUP)
184 -- Add all classes of the configuration group `a_group'.
185 require
186 a_group_not_void: a_group /= Void
187 do
188 if a_group.classes /= Void then
189 across a_group.classes as ic loop
190 add_class (ic.item)
191 end
192 end
193 end
194
195 add_classes (a_classes: attached ITERABLE [attached CONF_CLASS])
196 -- Add the classes `a_classes'.
197 do
198 system_wide_check := False
199
200 across a_classes as l_classes loop
201 add_class (l_classes.item)
202 end
203 end
204
205 add_class (a_class: attached CONF_CLASS)
206 -- Adds class `a_class'.
207 local
208 l_class_c: CLASS_C
209 do
210 system_wide_check := False
211
212 if attached {EIFFEL_CLASS_I} a_class as l_eiffel_class
213 and then attached l_eiffel_class.compiled_class as l_compiled
214 then
215 classes_to_analyze.extend (l_compiled)
216
217 extract_indexes (l_compiled)
218 else
219 output_actions.call ([ca_messages.class_skipped (a_class.name)])
220 end
221 end
222
223 feature -- Properties
224
225 is_running: BOOLEAN
226 -- Is code analysis running?
227
228 rules: LINKED_LIST [CA_RULE]
229 -- List of rules that will be used for analysis.
230
231 rule_violations: detachable HASH_TABLE [SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION], CLASS_C]
232 -- All found violations from the last analysis.
233
234 settings: CA_SETTINGS
235 -- The settings manager for Code Analysis.
236
237 preferences: PREFERENCES
238 -- Code Analysis preferences.
239 do Result := settings.preferences end
240
241 class_list: ITERABLE [CLASS_C]
242 -- List of classes that have been added.
243 do Result := classes_to_analyze end
244
245 feature {NONE} -- Implementation
246
247 csv_file_name: STRING = "last_analysis_result.csv"
248
249 csv_header: STRING = "Severity;Class;Location;Title;Description;Rule ID;Severity Score"
250
251 analysis_completed (a_exceptions: detachable ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]])
252 -- Will be called when the analysis task has finished. `a_exceptions'
253 -- contains a list of exception that occurred during analysis.
254 local
255 l_csv_writer: CA_CSV_WRITER
256 do
257 create l_csv_writer.make (csv_file_name, csv_header)
258
259 across rules as l_rules loop
260 across l_rules.item.violations as l_v loop
261 -- Check the ignore list.
262 if is_violation_valid (l_v.item) then
263 -- Make sure a list for this class exists in the hash table:
264 rule_violations.put (create {SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION]}.make, l_v.item.affected_class)
265 -- Add the violation.
266 rule_violations.at (l_v.item.affected_class).extend (l_v.item)
267 -- Log it.
268 l_csv_writer.add_line (l_v.item.csv_line)
269 end
270 end
271 end
272
273 l_csv_writer.close_file
274
275 clear_classes_to_analyze
276
277 is_running := False
278 completed_actions.call ([a_exceptions])
279 completed_actions.wipe_out
280 end
281
282 is_violation_valid (a_viol: attached CA_RULE_VIOLATION): BOOLEAN
283 -- Is the violation `a_viol' valid under the current settings
284 -- such as the rule ignore list of a class, or the library or
285 -- non-library status of a class?
286 local
287 l_affected_class: CLASS_C
288 l_rule: CA_RULE
289 do
290 l_affected_class := a_viol.affected_class
291 l_rule := a_viol.rule
292
293 Result := True
294
295 if ignoredby.has (l_affected_class)
296 and then (ignoredby.at (l_affected_class)).has (l_rule.id) then
297 Result := False
298 end
299
300 if (not l_rule.checks_library_classes) and then library_class.at (l_affected_class) then
301 Result := False
302 end
303
304 if (not l_rule.checks_nonlibrary_classes) and then nonlibrary_class.at (l_affected_class) then
305 Result := False
306 end
307 end
308
309 classes_to_analyze: LINKED_SET [CLASS_C]
310 -- List of classes that shall be analyzed.
311
312 system_wide_check: BOOLEAN
313 -- Shall the whole system be analyzed?
314
315 completed_actions: ACTION_SEQUENCE [TUPLE [ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]]]]
316 -- List of procedures to call when analysis has completed.
317
318 frozen rota: detachable ROTA_S
319 -- Accesses the rota service.
320 local
321 l_service_consumer: SERVICE_CONSUMER [ROTA_S]
322 do
323 create l_service_consumer
324 if attached l_service_consumer.service as l_service and then l_service.is_interface_usable then
325 Result := l_service
326 end
327 end
328
329 is_severity_enabled (a_severity: attached CA_RULE_SEVERITY): BOOLEAN
330 do
331 Result := (attached {CA_HINT} a_severity and settings.are_hints_enabled.value)
332 or else (attached {CA_SUGGESTION} a_severity and settings.are_suggestions_enabled.value)
333 or else (attached {CA_WARNING} a_severity and settings.are_warnings_enabled.value)
334 or else (attached {CA_ERROR} a_severity and settings.are_errors_enabled.value)
335 end
336
337 output_actions: ACTION_SEQUENCE [TUPLE [READABLE_STRING_GENERAL]]
338 -- Will be called whenever there is a message to output.
339
340 feature {NONE} -- Class-wide Options (From Indexing Clauses)
341
342 extract_indexes (a_class: attached CLASS_C)
343 -- Extracts options from the indexing clause of class `a_class'.
344 local
345 l_ast: CLASS_AS
346 l_ignoredby: LINKED_LIST [STRING_32]
347 do
348 create l_ignoredby.make
349 l_ignoredby.compare_objects -- We want to compare the actual strings.
350 -- Reset the class flags.
351 library_class.force (False, a_class)
352 nonlibrary_class.force (False, a_class)
353 l_ast := a_class.ast
354
355 if attached l_ast.internal_top_indexes as l_top then
356 search_indexing_tags (l_top, a_class, l_ignoredby)
357 end
358 if attached l_ast.internal_bottom_indexes as l_bottom then
359 search_indexing_tags (l_bottom, a_class, l_ignoredby)
360 end
361
362 ignoredby.force (l_ignoredby, a_class)
363 end
364
365 search_indexing_tags (a_clause: attached INDEXING_CLAUSE_AS; a_class: attached CLASS_C; a_ignoredby: attached LINKED_LIST [STRING_32])
366 -- Searches `a_clause' for settings relevant to code analysis.
367 local
368 l_item: STRING_32
369 do
370 across a_clause as ic loop
371 if ic.item.tag.name_32.is_equal ("ca_ignoredby") then
372 -- Class wants to ignore certain rules.
373 across ic.item.index_list as l_list loop
374 l_item := l_list.item.string_value_32
375 l_item.prune_all ('%"')
376 a_ignoredby.extend (l_item)
377 end
378 elseif ic.item.tag.name_32.is_equal ("ca_library") then
379 -- Class has information on whether it is a library class.
380 if not ic.item.index_list.is_empty then
381 l_item := ic.item.index_list.first.string_value_32
382 l_item.to_lower
383 l_item.prune_all ('%"')
384 if l_item.is_equal ("true") then
385 library_class.force (True, a_class)
386 elseif l_item.is_equal ("false") then
387 nonlibrary_class.force (True, a_class)
388 end
389 end
390 end
391 end
392 end
393
394 ignoredby: HASH_TABLE [LINKED_LIST [STRING_32], CLASS_C]
395 -- Maps classes to lists of rules (rule IDs) the class wants to be ignored by.
396
397 library_class, nonlibrary_class: HASH_TABLE [BOOLEAN, CLASS_C]
398 -- Stores classes that are marked as library or non-library classes.
399
400 invariant
401 -- law_of_non_contradiction: one class must not be both a library_class and a nonlibrary_class
402
403 end

Properties

Name Value
svn:eol-style native
svn:keywords Author Date ID Revision

  ViewVC Help
Powered by ViewVC 1.1.23