/[eiffelstudio]/branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e
ViewVC logotype

Contents of /branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e

Parent Directory Parent Directory | Revision Log Revision Log


Revision 94875 - (show annotations)
Wed Apr 16 17:42:14 2014 UTC (5 years, 10 months ago) by apaolo
File size: 14021 byte(s)
Rearranged Paolo's Inspector Eiffel rules into the proper folders.
Deleted incomplete rule "Attribute should be local" as a very similar one (CA064) already exists.
1 note
2 description: "THE Code Analyzer."
3 author: "Stefan Zurfluh"
4 date: "$Date$"
5 revision: "$Revision$"
6
7 class
8 CA_CODE_ANALYZER
9
10 inherit
11 SHARED_EIFFEL_PROJECT
12
13 CA_SHARED_NAMES
14
15 create
16 make
17
18 feature {NONE} -- Initialization
19
20 make
21 -- Initialization for `Current'.
22 do
23 create settings.make
24 create rules.make
25 -- Adding the rules.
26 rules.extend (create {CA_SELF_ASSIGNMENT_RULE}.make)
27 rules.extend (create {CA_UNUSED_ARGUMENT_RULE}.make)
28 rules.extend (create {CA_NPATH_RULE}.make (settings.preference_manager))
29 rules.extend (create {CA_EMPTY_IF_RULE}.make)
30 rules.extend (create {CA_FEATURE_NEVER_CALLED_RULE}.make)
31 rules.extend (create {CA_CQ_SEPARATION_RULE}.make)
32 rules.extend (create {CA_UNNEEDED_OT_LOCAL_RULE}.make)
33 rules.extend (create {CA_UNNEEDED_OBJECT_TEST_RULE}.make) -- Needs type info.
34 rules.extend (create {CA_NESTED_COMPLEXITY_RULE}.make (settings.preference_manager))
35 rules.extend (create {CA_MANY_ARGUMENTS_RULE}.make (settings.preference_manager))
36 rules.extend (create {CA_CREATION_PROC_EXPORTED_RULE}.make)
37 rules.extend (create {CA_VARIABLE_NOT_READ_RULE}.make)
38 rules.extend (create {CA_SEMICOLON_ARGUMENTS_RULE}.make)
39 rules.extend (create {CA_VERY_LONG_ROUTINE_RULE}.make (settings.preference_manager))
40 rules.extend (create {CA_VERY_BIG_CLASS_RULE}.make (settings.preference_manager))
41 rules.extend (create {CA_FEATURE_SECTION_COMMENT_RULE}.make)
42 rules.extend (create {CA_FEATURE_NOT_COMMENTED_RULE}.make)
43 rules.extend (create {CA_BOOLEAN_RESULT_RULE}.make)
44 rules.extend (create {CA_BOOLEAN_COMPARISON_RULE}.make)
45 rules.extend (create {CA_VERY_SHORT_IDENTIFIER_RULE}.make (settings.preference_manager))
46 rules.extend (create {CA_VERY_LONG_IDENTIFIER_RULE}.make (settings.preference_manager))
47 rules.extend (create {CA_MISSING_IS_EQUAL_RULE}.make)
48 rules.extend (create {CA_SIMPLIFIABLE_BOOLEAN_RULE}.make)
49 rules.extend (create {CA_SELF_COMPARISON_RULE}.make)
50 rules.extend (create {CA_TODO_RULE}.make)
51 rules.extend (create {CA_WRONG_LOOP_ITERATION_RULE}.make)
52 rules.extend (create {CA_INSPECT_INSTRUCTIONS_RULE}.make (settings.preference_manager))
53 rules.extend (create {CA_ATTRIBUTE_TO_LOCAL_RULE}.make)
54 rules.extend (create {CA_EMPTY_EFFECTIVE_ROUTINE_RULE}.make)
55 rules.extend (create {CA_IF_ELSE_NOT_EQUAL_RULE}.make)
56 rules.extend (create {CA_SHORT_CIRCUIT_IF_RULE}.make)
57 rules.extend (create {CA_ITERABLE_LOOP_RULE}.make) -- Needs type info.
58 rules.extend (create {CA_COUNT_EQUALS_ZERO_RULE}.make) -- Needs type info.
59 rules.extend (create {CA_DEEPLY_NESTED_IF_RULE}.make (settings.preference_manager))
60 rules.extend (create {CA_UNNEEDED_HELPER_VARIABLE_RULE}.make (settings.preference_manager))
61 rules.extend (create {CA_UNNEEDED_PARENTHESES_RULE}.make)
62 rules.extend (create {CA_CLASS_NAMING_CONVENTION_RULE}.make)
63 rules.extend (create {CA_FEATURE_NAMING_CONVENTION_RULE}.make)
64 rules.extend (create {CA_VARIABLE_NAMING_CONVENTION_RULE}.make (settings.preference_manager))
65 rules.extend (create {CA_ARGUMENT_NAMING_CONVENTION_RULE}.make (settings.preference_manager))
66 rules.extend (create {CA_UNNECESSARY_SIGN_OPERATOR_RULE}.make)
67 rules.extend (create {CA_EMPTY_UNCOMMENTED_ROUTINE_RULE}.make)
68 rules.extend (create {CA_UNNEEDED_ACCESSOR_FUNCTION_RULE}.make)
69 rules.extend (create {CA_MERGEABLE_FEATURE_CLAUSES_RULE}.make)
70 rules.extend (create {CA_EMPTY_RESCUE_CLAUSE_RULE}.make)
71 rules.extend (create {CA_INSPECT_NO_WHEN_RULE}.make)
72 rules.extend (create {CA_EXPLICIT_REDUNDANT_INHERITANCE_RULE}.make)
73
74 settings.initialize_rule_settings (rules)
75
76 create classes_to_analyze.make
77 create rule_violations.make (100)
78 create completed_actions
79 create output_actions
80
81 create ignoredby.make (25)
82 create library_class.make (25)
83 create nonlibrary_class.make (25)
84 end
85
86 feature -- Analysis interface
87
88 add_completed_action (a_action: attached PROCEDURE [ANY, TUPLE [ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]]]])
89 -- Adds `a_action' to the list of procedures that will be
90 -- called when analysis has completed.
91 do
92 completed_actions.extend (a_action)
93 end
94
95 add_output_action (a_action: attached PROCEDURE [ANY, TUPLE [READABLE_STRING_GENERAL]])
96 -- Adds `a_action' to the procedures that are called for outputting status. The final results
97 -- (rule violations) are not given to these procedures.
98 do
99 output_actions.extend (a_action)
100 end
101
102 analyze
103 -- Analyze all the classes that have been added.
104 require
105 not is_running
106 local
107 l_rules_checker: CA_ALL_RULES_CHECKER
108 l_task: CA_RULE_CHECKING_TASK
109 l_rules_to_check: LINKED_LIST [CA_RULE]
110 do
111 is_running := True
112
113 create l_rules_checker.make
114 create l_rules_to_check.make
115 across rules as l_rules loop
116 l_rules.item.clear_violations
117 if is_rule_checkable (l_rules.item) then
118 l_rules_to_check.extend (l_rules.item)
119 -- Here we only prepare standard rules. The rule checking task will iterate again
120 -- through the rules and run the analysis on the enabled rules.
121 if attached {CA_STANDARD_RULE} l_rules.item as l_std_rule then
122 l_std_rule.prepare_checking (l_rules_checker)
123 end
124 end
125 end
126
127 create l_task.make (l_rules_checker, l_rules_to_check, classes_to_analyze, agent analysis_completed)
128 l_task.set_output_actions (output_actions)
129 rota.run_task (l_task)
130 end
131
132 is_rule_checkable (a_rule: attached CA_RULE): BOOLEAN
133 -- Will `a_rule' be checked based on the current preferences and based on the current
134 -- checking scope?
135 do
136 Result := a_rule.is_enabled.value
137 and then (system_wide_check or else (not a_rule.is_system_wide))
138 and then is_severity_enabled (a_rule.severity)
139 end
140
141 clear_classes_to_analyze
142 -- Removes all classes that have been added to the list of classes
143 -- to analyze.
144 do
145 classes_to_analyze.wipe_out
146 end
147
148 add_whole_system
149 -- Adds all the classes that are part of the current system. Classes of referenced libraries
150 -- will not be added.
151 local
152 l_cluster: CLUSTER_I
153 do
154 across
155 eiffel_universe.groups as l_groups
156 loop
157 l_cluster ?= l_groups.item
158 -- Only load top-level clusters, as the others will be loaded recursively afterwards.
159 if l_cluster /= Void and then l_cluster.parent_cluster = Void then
160 add_cluster (l_cluster)
161 end
162 end
163
164 system_wide_check := True
165 end
166
167 add_cluster (a_cluster: attached CLUSTER_I)
168 -- Add all classes of cluster `a_cluster'.
169 do
170 system_wide_check := False
171
172 if a_cluster.classes /= Void then
173 across a_cluster.classes as ic loop
174 add_class (ic.item)
175 end
176 end
177
178 if a_cluster.sub_clusters /= Void then
179 across a_cluster.sub_clusters as ic loop
180 add_cluster (ic.item)
181 end
182 end
183 end
184
185 add_group (a_group: attached CONF_GROUP)
186 -- Add all classes of the configuration group `a_group'.
187 require
188 a_group_not_void: a_group /= Void
189 do
190 if a_group.classes /= Void then
191 across a_group.classes as ic loop
192 add_class (ic.item)
193 end
194 end
195 end
196
197 add_classes (a_classes: attached ITERABLE [attached CONF_CLASS])
198 -- Add the classes `a_classes'.
199 do
200 system_wide_check := False
201
202 across a_classes as l_classes loop
203 add_class (l_classes.item)
204 end
205 end
206
207 add_class (a_class: attached CONF_CLASS)
208 -- Adds class `a_class'.
209 local
210 l_class_c: CLASS_C
211 do
212 system_wide_check := False
213
214 if attached {EIFFEL_CLASS_I} a_class as l_eiffel_class
215 and then attached l_eiffel_class.compiled_class as l_compiled
216 then
217 classes_to_analyze.extend (l_compiled)
218
219 extract_indexes (l_compiled)
220 else
221 output_actions.call ([ca_messages.class_skipped (a_class.name)])
222 end
223 end
224
225 feature -- Properties
226
227 is_running: BOOLEAN
228 -- Is code analysis running?
229
230 rules: LINKED_LIST [CA_RULE]
231 -- List of rules that will be used for analysis.
232
233 rule_violations: detachable HASH_TABLE [SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION], CLASS_C]
234 -- All found violations from the last analysis.
235
236 settings: CA_SETTINGS
237 -- The settings manager for Code Analysis.
238
239 preferences: PREFERENCES
240 -- Code Analysis preferences.
241 do Result := settings.preferences end
242
243 class_list: ITERABLE [CLASS_C]
244 -- List of classes that have been added.
245 do Result := classes_to_analyze end
246
247 feature {NONE} -- Implementation
248
249 csv_file_name: STRING = "last_analysis_result.csv"
250
251 csv_header: STRING = "Severity;Class;Location;Title;Description;Rule ID;Severity Score"
252
253 analysis_completed (a_exceptions: detachable ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]])
254 -- Will be called when the analysis task has finished. `a_exceptions'
255 -- contains a list of exception that occurred during analysis.
256 local
257 l_csv_writer: CA_CSV_WRITER
258 do
259 create l_csv_writer.make (csv_file_name, csv_header)
260
261 across rules as l_rules loop
262 across l_rules.item.violations as l_v loop
263 -- Check the ignore list.
264 if is_violation_valid (l_v.item) then
265 -- Make sure a list for this class exists in the hash table:
266 rule_violations.put (create {SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION]}.make, l_v.item.affected_class)
267 -- Add the violation.
268 rule_violations.at (l_v.item.affected_class).extend (l_v.item)
269 -- Log it.
270 l_csv_writer.add_line (l_v.item.csv_line)
271 end
272 end
273 end
274
275 l_csv_writer.close_file
276
277 clear_classes_to_analyze
278
279 is_running := False
280 completed_actions.call ([a_exceptions])
281 completed_actions.wipe_out
282 end
283
284 is_violation_valid (a_viol: attached CA_RULE_VIOLATION): BOOLEAN
285 -- Is the violation `a_viol' valid under the current settings
286 -- such as the rule ignore list of a class, or the library or
287 -- non-library status of a class?
288 local
289 l_affected_class: CLASS_C
290 l_rule: CA_RULE
291 do
292 l_affected_class := a_viol.affected_class
293 l_rule := a_viol.rule
294
295 Result := True
296
297 if ignoredby.has (l_affected_class)
298 and then (ignoredby.at (l_affected_class)).has (l_rule.id) then
299 Result := False
300 end
301
302 if (not l_rule.checks_library_classes) and then library_class.at (l_affected_class) then
303 Result := False
304 end
305
306 if (not l_rule.checks_nonlibrary_classes) and then nonlibrary_class.at (l_affected_class) then
307 Result := False
308 end
309 end
310
311 classes_to_analyze: LINKED_SET [CLASS_C]
312 -- List of classes that shall be analyzed.
313
314 system_wide_check: BOOLEAN
315 -- Shall the whole system be analyzed?
316
317 completed_actions: ACTION_SEQUENCE [TUPLE [ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]]]]
318 -- List of procedures to call when analysis has completed.
319
320 frozen rota: detachable ROTA_S
321 -- Accesses the rota service.
322 local
323 l_service_consumer: SERVICE_CONSUMER [ROTA_S]
324 do
325 create l_service_consumer
326 if attached l_service_consumer.service as l_service and then l_service.is_interface_usable then
327 Result := l_service
328 end
329 end
330
331 is_severity_enabled (a_severity: attached CA_RULE_SEVERITY): BOOLEAN
332 do
333 Result := (attached {CA_HINT} a_severity and settings.are_hints_enabled.value)
334 or else (attached {CA_SUGGESTION} a_severity and settings.are_suggestions_enabled.value)
335 or else (attached {CA_WARNING} a_severity and settings.are_warnings_enabled.value)
336 or else (attached {CA_ERROR} a_severity and settings.are_errors_enabled.value)
337 end
338
339 output_actions: ACTION_SEQUENCE [TUPLE [READABLE_STRING_GENERAL]]
340 -- Will be called whenever there is a message to output.
341
342 feature {NONE} -- Class-wide Options (From Indexing Clauses)
343
344 extract_indexes (a_class: attached CLASS_C)
345 -- Extracts options from the indexing clause of class `a_class'.
346 local
347 l_ast: CLASS_AS
348 l_ignoredby: LINKED_LIST [STRING_32]
349 do
350 create l_ignoredby.make
351 l_ignoredby.compare_objects -- We want to compare the actual strings.
352 -- Reset the class flags.
353 library_class.force (False, a_class)
354 nonlibrary_class.force (False, a_class)
355 l_ast := a_class.ast
356
357 if attached l_ast.internal_top_indexes as l_top then
358 search_indexing_tags (l_top, a_class, l_ignoredby)
359 end
360 if attached l_ast.internal_bottom_indexes as l_bottom then
361 search_indexing_tags (l_bottom, a_class, l_ignoredby)
362 end
363
364 ignoredby.force (l_ignoredby, a_class)
365 end
366
367 search_indexing_tags (a_clause: attached INDEXING_CLAUSE_AS; a_class: attached CLASS_C; a_ignoredby: attached LINKED_LIST [STRING_32])
368 -- Searches `a_clause' for settings relevant to code analysis.
369 local
370 l_item: STRING_32
371 do
372 across a_clause as ic loop
373 if ic.item.tag.name_32.is_equal ("ca_ignoredby") then
374 -- Class wants to ignore certain rules.
375 across ic.item.index_list as l_list loop
376 l_item := l_list.item.string_value_32
377 l_item.prune_all ('%"')
378 a_ignoredby.extend (l_item)
379 end
380 elseif ic.item.tag.name_32.is_equal ("ca_library") then
381 -- Class has information on whether it is a library class.
382 if not ic.item.index_list.is_empty then
383 l_item := ic.item.index_list.first.string_value_32
384 l_item.to_lower
385 l_item.prune_all ('%"')
386 if l_item.is_equal ("true") then
387 library_class.force (True, a_class)
388 elseif l_item.is_equal ("false") then
389 nonlibrary_class.force (True, a_class)
390 end
391 end
392 end
393 end
394 end
395
396 ignoredby: HASH_TABLE [LINKED_LIST [STRING_32], CLASS_C]
397 -- Maps classes to lists of rules (rule IDs) the class wants to be ignored by.
398
399 library_class, nonlibrary_class: HASH_TABLE [BOOLEAN, CLASS_C]
400 -- Stores classes that are marked as library or non-library classes.
401
402 invariant
403 -- law_of_non_contradiction: one class must not be both a library_class and a nonlibrary_class
404
405 end

Properties

Name Value
svn:eol-style native
svn:keywords Author Date ID Revision

  ViewVC Help
Powered by ViewVC 1.1.23