/[eiffelstudio]/branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e
ViewVC logotype

Contents of /branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e

Parent Directory Parent Directory | Revision Log Revision Log


Revision 95757 - (show annotations)
Fri Sep 12 12:25:28 2014 UTC (5 years, 4 months ago) by schmisam
File size: 15807 byte(s)
Added Unreachable Code rule and rule for invariant loop computation within loop
Reworked object_creation_within_loop_fix to work for several rules
Added tests for the new rules

1 note
2 description: "THE Code Analyzer."
3 author: "Stefan Zurfluh"
4 date: "$Date$"
5 revision: "$Revision$"
6
7 class
8 CA_CODE_ANALYZER
9
10 inherit
11 SHARED_EIFFEL_PROJECT
12
13 CA_SHARED_NAMES
14
15 create
16 make
17
18 feature {NONE} -- Initialization
19
20 make
21 -- Initialization for `Current'.
22 do
23 create settings.make
24 create rules.make_caseless (100) -- Rule IDs should be case insensitive.
25
26 -- Adding the rules.
27 add_rule (create {CA_SELF_ASSIGNMENT_RULE}.make)
28 add_rule (create {CA_UNUSED_ARGUMENT_RULE}.make)
29 add_rule (create {CA_NPATH_RULE}.make (settings.preference_manager))
30 add_rule (create {CA_EMPTY_IF_RULE}.make)
31 add_rule (create {CA_FEATURE_NEVER_CALLED_RULE}.make)
32 add_rule (create {CA_CQ_SEPARATION_RULE}.make)
33 add_rule (create {CA_UNNEEDED_OT_LOCAL_RULE}.make)
34 add_rule (create {CA_UNNEEDED_OBJECT_TEST_RULE}.make) -- Needs type info.
35 add_rule (create {CA_NESTED_COMPLEXITY_RULE}.make (settings.preference_manager))
36 add_rule (create {CA_MANY_ARGUMENTS_RULE}.make (settings.preference_manager))
37 add_rule (create {CA_CREATION_PROC_EXPORTED_RULE}.make)
38 add_rule (create {CA_VARIABLE_NOT_READ_RULE}.make)
39 add_rule (create {CA_SEMICOLON_ARGUMENTS_RULE}.make)
40 add_rule (create {CA_VERY_LONG_ROUTINE_RULE}.make (settings.preference_manager))
41 add_rule (create {CA_VERY_BIG_CLASS_RULE}.make (settings.preference_manager))
42 add_rule (create {CA_FEATURE_SECTION_COMMENT_RULE}.make)
43 add_rule (create {CA_FEATURE_NOT_COMMENTED_RULE}.make)
44 add_rule (create {CA_BOOLEAN_RESULT_RULE}.make)
45 add_rule (create {CA_BOOLEAN_COMPARISON_RULE}.make)
46 add_rule (create {CA_VERY_SHORT_IDENTIFIER_RULE}.make (settings.preference_manager))
47 add_rule (create {CA_VERY_LONG_IDENTIFIER_RULE}.make (settings.preference_manager))
48 add_rule (create {CA_MISSING_IS_EQUAL_RULE}.make)
49 add_rule (create {CA_SIMPLIFIABLE_BOOLEAN_RULE}.make)
50 add_rule (create {CA_SELF_COMPARISON_RULE}.make)
51 add_rule (create {CA_TODO_RULE}.make)
52 add_rule (create {CA_WRONG_LOOP_ITERATION_RULE}.make)
53 add_rule (create {CA_INSPECT_INSTRUCTIONS_RULE}.make (settings.preference_manager))
54 add_rule (create {CA_ATTRIBUTE_TO_LOCAL_RULE}.make)
55 add_rule (create {CA_EMPTY_EFFECTIVE_ROUTINE_RULE}.make)
56 add_rule (create {CA_IF_ELSE_NOT_EQUAL_RULE}.make)
57 add_rule (create {CA_SHORT_CIRCUIT_IF_RULE}.make)
58 add_rule (create {CA_ITERABLE_LOOP_RULE}.make) -- Needs type info.
59 add_rule (create {CA_COUNT_EQUALS_ZERO_RULE}.make) -- Needs type info.
60 add_rule (create {CA_DEEPLY_NESTED_IF_RULE}.make (settings.preference_manager))
61 add_rule (create {CA_UNNEEDED_HELPER_VARIABLE_RULE}.make (settings.preference_manager))
62 add_rule (create {CA_UNNEEDED_PARENTHESES_RULE}.make)
63 add_rule (create {CA_CLASS_NAMING_CONVENTION_RULE}.make)
64 add_rule (create {CA_FEATURE_NAMING_CONVENTION_RULE}.make)
65 add_rule (create {CA_LOCAL_NAMING_CONVENTION_RULE}.make (settings.preference_manager))
66 add_rule (create {CA_ARGUMENT_NAMING_CONVENTION_RULE}.make (settings.preference_manager))
67 add_rule (create {CA_UNNECESSARY_SIGN_OPERATOR_RULE}.make)
68 add_rule (create {CA_EMPTY_UNCOMMENTED_ROUTINE_RULE}.make)
69 add_rule (create {CA_UNNEEDED_ACCESSOR_FUNCTION_RULE}.make)
70 add_rule (create {CA_MERGEABLE_FEATURE_CLAUSES_RULE}.make)
71 add_rule (create {CA_EMPTY_RESCUE_CLAUSE_RULE}.make)
72 add_rule (create {CA_INSPECT_NO_WHEN_RULE}.make)
73 add_rule (create {CA_EXPLICIT_REDUNDANT_INHERITANCE_RULE}.make)
74 add_rule (create {CA_UNDESIRABLE_COMMENT_CONTENT_RULE}.make (settings.preference_manager))
75 add_rule (create {CA_INHERIT_FROM_ANY_RULE}.make)
76 add_rule (create {CA_DOUBLE_NEGATION_RULE}.make)
77 add_rule (create {CA_EMPTY_LOOP_RULE}.make)
78 add_rule (create {CA_MISSING_CREATION_PROC_WITHOUT_ARGS_RULE}.make)
79 add_rule (create {CA_COMMENT_NOT_WELL_PHRASED_RULE}.make)
80 add_rule (create {CA_OBJECT_CREATION_WITHIN_LOOP_RULE}.make)
81 add_rule (create {CA_EMPTY_CREATION_PROC_RULE}.make)
82 add_rule (create {CA_VOID_CHECK_USING_IS_EQUAL_RULE}.make)
83 add_rule (create {CA_COMPARISON_OF_OBJECT_REFS_RULE}.make)
84 add_rule (create {CA_ATTRIBUTE_CAN_BE_CONSTANT_RULE}.make)
85 add_rule (create {CA_LOOP_INVARIANT_COMPUTATION_RULE}.make)
86 add_rule (create {CA_UNREACHABLE_CODE_RULE}.make)
87
88 settings.initialize_rule_settings (rules)
89
90 create classes_to_analyze.make
91 create rule_violations.make (100)
92 create completed_actions
93 create output_actions
94
95 create ignoredby.make (25)
96 create library_class.make (25)
97 create nonlibrary_class.make (25)
98 end
99
100 feature -- Analysis interface
101
102 add_completed_action (a_action: attached PROCEDURE [ANY, TUPLE [ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]]]])
103 -- Adds `a_action' to the list of procedures that will be
104 -- called when analysis has completed.
105 do
106 completed_actions.extend (a_action)
107 end
108
109 add_output_action (a_action: attached PROCEDURE [ANY, TUPLE [READABLE_STRING_GENERAL]])
110 -- Adds `a_action' to the procedures that are called for outputting status. The final results
111 -- (rule violations) are not given to these procedures.
112 do
113 output_actions.extend (a_action)
114 end
115
116 analyze
117 -- Analyze all the classes that have been added.
118 require
119 not is_running
120 local
121 l_rules_checker: CA_ALL_RULES_CHECKER
122 l_task: CA_RULE_CHECKING_TASK
123 l_rules_to_check: LINKED_LIST [CA_RULE]
124 do
125 is_running := True
126
127 create l_rules_checker.make
128 create l_rules_to_check.make
129 across rules as l_rules loop
130 l_rules.item.clear_violations
131 if is_rule_checkable (l_rules.item) then
132 l_rules_to_check.extend (l_rules.item)
133 -- Here we only prepare standard rules. The rule checking task will iterate again
134 -- through the rules and run the analysis on the enabled rules.
135 if attached {CA_STANDARD_RULE} l_rules.item as l_std_rule then
136 l_std_rule.prepare_checking (l_rules_checker)
137 end
138 end
139 end
140
141 create l_task.make (l_rules_checker, l_rules_to_check, classes_to_analyze, agent analysis_completed)
142 l_task.set_output_actions (output_actions)
143 if attached rota as l_rota then
144 rota.run_task (l_task)
145 else
146 -- No ROTA task is available, we execute the task synchronously.
147 from
148
149 until
150 not l_task.has_next_step
151 loop
152 l_task.step
153 end
154 end
155 end
156
157 is_rule_checkable (a_rule: attached CA_RULE): BOOLEAN
158 -- Will `a_rule' be checked based on the current preferences and based on the current
159 -- checking scope?
160 do
161 Result := a_rule.is_enabled.value
162 and then (system_wide_check or else (not a_rule.is_system_wide))
163 and then is_severity_enabled (a_rule.severity)
164 end
165
166 clear_classes_to_analyze
167 -- Removes all classes that have been added to the list of classes
168 -- to analyze.
169 do
170 classes_to_analyze.wipe_out
171 end
172
173 add_whole_system
174 -- Adds all the classes that are part of the current system. Classes of referenced libraries
175 -- will not be added.
176 do
177 across
178 eiffel_universe.groups as l_groups
179 loop
180 -- Only load top-level clusters, as the others will be loaded recursively afterwards.
181 if attached {CLUSTER_I} l_groups.item as l_cluster and then l_cluster.parent_cluster = Void then
182 add_cluster (l_cluster)
183 end
184 end
185
186 system_wide_check := True
187 end
188
189 add_cluster (a_cluster: attached CLUSTER_I)
190 -- Add all classes of cluster `a_cluster'.
191 do
192 system_wide_check := False
193
194 if a_cluster.classes /= Void then
195 across a_cluster.classes as ic loop
196 add_class (ic.item)
197 end
198 end
199
200 if a_cluster.sub_clusters /= Void then
201 across a_cluster.sub_clusters as ic loop
202 add_cluster (ic.item)
203 end
204 end
205 end
206
207 add_group (a_group: attached CONF_GROUP)
208 -- Add all classes of the configuration group `a_group'.
209 require
210 a_group_not_void: a_group /= Void
211 do
212 if a_group.classes /= Void then
213 across a_group.classes as ic loop
214 add_class (ic.item)
215 end
216 end
217 end
218
219 add_classes (a_classes: attached ITERABLE [attached CONF_CLASS])
220 -- Add the classes `a_classes'.
221 do
222 system_wide_check := False
223
224 across a_classes as l_classes loop
225 add_class (l_classes.item)
226 end
227 end
228
229 add_class (a_class: attached CONF_CLASS)
230 -- Adds class `a_class'.
231 do
232 system_wide_check := False
233
234 if attached {EIFFEL_CLASS_I} a_class as l_eiffel_class
235 and then attached l_eiffel_class.compiled_class as l_compiled
236 then
237 classes_to_analyze.extend (l_compiled)
238
239 extract_indexes (l_compiled)
240 else
241 output_actions.call ([ca_messages.class_skipped (a_class.name)])
242 end
243 end
244
245
246 force_preferences (a_preferences: LIST [TUPLE [rule_id: READABLE_STRING_GENERAL; preference_name: STRING; preference_value: READABLE_STRING_GENERAL]])
247 -- Forcefully set the preferences in `a_preferences' to the specified values,
248 -- overwriting the current ones.
249 local
250 l_full_preference_name: STRING
251 l_preference: PREFERENCE
252 do
253 -- Disable all rules.
254 across rules as ic loop
255 ic.item.is_enabled.set_value (False)
256 end
257
258 across a_preferences as ic loop
259 if rules.has_key (ic.item.rule_id) then
260 l_full_preference_name := rules.found_item.full_preference_name (ic.item.preference_name)
261 l_preference := preferences.get_preference (l_full_preference_name)
262
263 if attached l_preference then
264 l_preference.set_value_from_string (ic.item.preference_value)
265 else
266 output_actions.call ([ca_messages.preference_not_found (l_full_preference_name)])
267 end
268
269 else
270 output_actions.call ([ca_messages.rule_not_found (ic.item.rule_id)])
271 end
272 end
273 end
274
275
276 feature -- Properties
277
278 is_running: BOOLEAN
279 -- Is code analysis running?
280
281 rules: STRING_TABLE [CA_RULE]
282 -- Table containing the rules that will be used for analysis. Rules are indexed by ID.
283
284 add_rule (a_rule: CA_RULE)
285 -- Adds `a_rule' to the rules list.
286 require
287 not_added_yet: not rules.has (a_rule.id)
288 do
289 rules.extend (a_rule, a_rule.id)
290 ensure
291 added: rules.has (a_rule.id)
292 end
293
294 rule_violations: detachable HASH_TABLE [SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION], CLASS_C]
295 -- All found violations from the last analysis.
296
297 settings: CA_SETTINGS
298 -- The settings manager for Code Analysis.
299
300 preferences: PREFERENCES
301 -- Code Analysis preferences.
302 do Result := settings.preferences end
303
304 class_list: ITERABLE [CLASS_C]
305 -- List of classes that have been added.
306 do Result := classes_to_analyze end
307
308 feature {NONE} -- Implementation
309
310 csv_file_name: STRING = "last_analysis_result.csv"
311
312 csv_header: STRING = "Severity;Class;Location;Title;Description;Rule ID;Severity Score"
313
314 analysis_completed (a_exceptions: detachable ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]])
315 -- Will be called when the analysis task has finished. `a_exceptions'
316 -- contains a list of exception that occurred during analysis.
317 local
318 l_csv_writer: CA_CSV_WRITER
319 do
320 create l_csv_writer.make (eiffel_project.project_location.target_path.extended (csv_file_name), csv_header)
321
322 across rules as l_rules loop
323 across l_rules.item.violations as l_v loop
324 -- Check the ignore list.
325 if is_violation_valid (l_v.item) then
326 -- Make sure a list for this class exists in the hash table:
327 rule_violations.put (create {SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION]}.make, l_v.item.affected_class)
328 -- Add the violation.
329 rule_violations.at (l_v.item.affected_class).extend (l_v.item)
330 -- Log it.
331 l_csv_writer.add_line (l_v.item.csv_line)
332 end
333 end
334 end
335
336 l_csv_writer.close_file
337
338 clear_classes_to_analyze
339
340 is_running := False
341 completed_actions.call ([a_exceptions])
342 completed_actions.wipe_out
343 end
344
345 is_violation_valid (a_viol: attached CA_RULE_VIOLATION): BOOLEAN
346 -- Is the violation `a_viol' valid under the current settings
347 -- such as the rule ignore list of a class, or the library or
348 -- non-library status of a class?
349 local
350 l_affected_class: CLASS_C
351 l_rule: CA_RULE
352 do
353 l_affected_class := a_viol.affected_class
354 l_rule := a_viol.rule
355
356 Result := True
357
358 if ignoredby.has (l_affected_class)
359 and then (ignoredby.at (l_affected_class)).has (l_rule.id) then
360 Result := False
361 end
362
363 if (not l_rule.checks_library_classes) and then library_class.at (l_affected_class) then
364 Result := False
365 end
366
367 if (not l_rule.checks_nonlibrary_classes) and then nonlibrary_class.at (l_affected_class) then
368 Result := False
369 end
370 end
371
372 classes_to_analyze: LINKED_SET [CLASS_C]
373 -- List of classes that shall be analyzed.
374
375 system_wide_check: BOOLEAN
376 -- Shall the whole system be analyzed?
377
378 completed_actions: ACTION_SEQUENCE [TUPLE [ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]]]]
379 -- List of procedures to call when analysis has completed.
380
381 frozen rota: detachable ROTA_S
382 -- Accesses the rota service.
383 local
384 l_service_consumer: SERVICE_CONSUMER [ROTA_S]
385 do
386 create l_service_consumer
387 if attached l_service_consumer.service as l_service and then l_service.is_interface_usable then
388 Result := l_service
389 end
390 end
391
392 is_severity_enabled (a_severity: attached CA_RULE_SEVERITY): BOOLEAN
393 do
394 Result := (attached {CA_HINT} a_severity and settings.are_hints_enabled.value)
395 or else (attached {CA_SUGGESTION} a_severity and settings.are_suggestions_enabled.value)
396 or else (attached {CA_WARNING} a_severity and settings.are_warnings_enabled.value)
397 or else (attached {CA_ERROR} a_severity and settings.are_errors_enabled.value)
398 end
399
400 output_actions: ACTION_SEQUENCE [TUPLE [READABLE_STRING_GENERAL]]
401 -- Will be called whenever there is a message to output.
402
403 feature {NONE} -- Class-wide Options (From Indexing Clauses)
404
405 extract_indexes (a_class: attached CLASS_C)
406 -- Extracts options from the indexing clause of class `a_class'.
407 local
408 l_ast: CLASS_AS
409 l_ignoredby: LINKED_LIST [STRING_32]
410 do
411 create l_ignoredby.make
412 l_ignoredby.compare_objects -- We want to compare the actual strings.
413 -- Reset the class flags.
414 library_class.force (False, a_class)
415 nonlibrary_class.force (False, a_class)
416 l_ast := a_class.ast
417
418 if attached l_ast.internal_top_indexes as l_top then
419 search_indexing_tags (l_top, a_class, l_ignoredby)
420 end
421 if attached l_ast.internal_bottom_indexes as l_bottom then
422 search_indexing_tags (l_bottom, a_class, l_ignoredby)
423 end
424
425 ignoredby.force (l_ignoredby, a_class)
426 end
427
428 search_indexing_tags (a_clause: attached INDEXING_CLAUSE_AS; a_class: attached CLASS_C; a_ignoredby: attached LINKED_LIST [STRING_32])
429 -- Searches `a_clause' for settings relevant to code analysis.
430 local
431 l_item: STRING_32
432 do
433 across a_clause as ic loop
434 if attached ic.item.tag as l_tag then
435 if l_tag.name_32.same_string_general ("ca_ignoredby") then
436 -- Class wants to ignore certain rules.
437 across ic.item.index_list as l_list loop
438 l_item := l_list.item.string_value_32
439 l_item.prune_all ('%"')
440 a_ignoredby.extend (l_item)
441 end
442 elseif l_tag.name_32.is_equal ("ca_library") then
443 -- Class has information on whether it is a library class.
444 if not ic.item.index_list.is_empty then
445 l_item := ic.item.index_list.first.string_value_32
446 l_item.to_lower
447 l_item.prune_all ('%"')
448 if l_item.is_equal ("true") then
449 library_class.force (True, a_class)
450 elseif l_item.is_equal ("false") then
451 nonlibrary_class.force (True, a_class)
452 end
453 end
454 end
455 end
456 end
457 end
458
459 ignoredby: HASH_TABLE [LINKED_LIST [STRING_32], CLASS_C]
460 -- Maps classes to lists of rules (rule IDs) the class wants to be ignored by.
461
462 library_class, nonlibrary_class: HASH_TABLE [BOOLEAN, CLASS_C]
463 -- Stores classes that are marked as library or non-library classes.
464
465 invariant
466 -- law_of_non_contradiction: one class must not be both a library_class and a nonlibrary_class
467
468 end

Properties

Name Value
svn:eol-style native
svn:keywords Author Date ID Revision

  ViewVC Help
Powered by ViewVC 1.1.23