/[eiffelstudio]/branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e
ViewVC logotype

Contents of /branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e

Parent Directory Parent Directory | Revision Log Revision Log


Revision 95832 - (show annotations)
Wed Oct 1 21:50:22 2014 UTC (5 years, 3 months ago) by schmisam
File size: 15912 byte(s)
Reverted base2 dependency on code_analysis/tests
Added tests.ecf file to ignored files (in case somebody wants to add other libraries for testing without commiting)

1 note
2 description: "THE Code Analyzer."
3 author: "Stefan Zurfluh"
4 date: "$Date$"
5 revision: "$Revision$"
6
7 class
8 CA_CODE_ANALYZER
9
10 inherit
11 SHARED_EIFFEL_PROJECT
12
13 CA_SHARED_NAMES
14
15 create
16 make
17
18 feature {NONE} -- Initialization
19
20 make
21 -- Initialization for `Current'.
22 do
23 create settings.make
24 create rules.make_caseless (100) -- Rule IDs should be case insensitive.
25
26 -- Adding the rules.
27 add_rule (create {CA_SELF_ASSIGNMENT_RULE}.make)
28 add_rule (create {CA_UNUSED_ARGUMENT_RULE}.make)
29 add_rule (create {CA_NPATH_RULE}.make (settings.preference_manager))
30 add_rule (create {CA_EMPTY_IF_RULE}.make)
31 add_rule (create {CA_FEATURE_NEVER_CALLED_RULE}.make)
32 add_rule (create {CA_CQ_SEPARATION_RULE}.make)
33 add_rule (create {CA_UNNEEDED_OT_LOCAL_RULE}.make)
34 add_rule (create {CA_UNNEEDED_OBJECT_TEST_RULE}.make)
35 add_rule (create {CA_NESTED_COMPLEXITY_RULE}.make (settings.preference_manager))
36 add_rule (create {CA_MANY_ARGUMENTS_RULE}.make (settings.preference_manager))
37 add_rule (create {CA_CREATION_PROC_EXPORTED_RULE}.make)
38 add_rule (create {CA_VARIABLE_NOT_READ_RULE}.make)
39 add_rule (create {CA_SEMICOLON_ARGUMENTS_RULE}.make)
40 add_rule (create {CA_VERY_LONG_ROUTINE_RULE}.make (settings.preference_manager))
41 add_rule (create {CA_VERY_BIG_CLASS_RULE}.make (settings.preference_manager))
42 add_rule (create {CA_FEATURE_SECTION_COMMENT_RULE}.make)
43 add_rule (create {CA_FEATURE_NOT_COMMENTED_RULE}.make)
44 add_rule (create {CA_BOOLEAN_RESULT_RULE}.make)
45 add_rule (create {CA_BOOLEAN_COMPARISON_RULE}.make)
46 add_rule (create {CA_VERY_SHORT_IDENTIFIER_RULE}.make (settings.preference_manager))
47 add_rule (create {CA_VERY_LONG_IDENTIFIER_RULE}.make (settings.preference_manager))
48 add_rule (create {CA_MISSING_IS_EQUAL_RULE}.make)
49 add_rule (create {CA_SIMPLIFIABLE_BOOLEAN_RULE}.make)
50 add_rule (create {CA_SELF_COMPARISON_RULE}.make)
51 add_rule (create {CA_TODO_RULE}.make)
52 add_rule (create {CA_WRONG_LOOP_ITERATION_RULE}.make)
53 add_rule (create {CA_INSPECT_INSTRUCTIONS_RULE}.make (settings.preference_manager))
54 add_rule (create {CA_ATTRIBUTE_TO_LOCAL_RULE}.make)
55 add_rule (create {CA_EMPTY_EFFECTIVE_ROUTINE_RULE}.make)
56 add_rule (create {CA_IF_ELSE_NOT_EQUAL_RULE}.make)
57 add_rule (create {CA_SHORT_CIRCUIT_IF_RULE}.make)
58 add_rule (create {CA_ITERABLE_LOOP_RULE}.make)
59 add_rule (create {CA_COUNT_EQUALS_ZERO_RULE}.make)
60 add_rule (create {CA_DEEPLY_NESTED_IF_RULE}.make (settings.preference_manager))
61 add_rule (create {CA_UNNEEDED_HELPER_VARIABLE_RULE}.make (settings.preference_manager))
62 add_rule (create {CA_UNNEEDED_PARENTHESES_RULE}.make)
63 add_rule (create {CA_CLASS_NAMING_CONVENTION_RULE}.make)
64 add_rule (create {CA_FEATURE_NAMING_CONVENTION_RULE}.make)
65 add_rule (create {CA_LOCAL_NAMING_CONVENTION_RULE}.make (settings.preference_manager))
66 add_rule (create {CA_ARGUMENT_NAMING_CONVENTION_RULE}.make (settings.preference_manager))
67 add_rule (create {CA_UNNECESSARY_SIGN_OPERATOR_RULE}.make)
68 add_rule (create {CA_EMPTY_UNCOMMENTED_ROUTINE_RULE}.make)
69 add_rule (create {CA_UNNEEDED_ACCESSOR_FUNCTION_RULE}.make)
70 add_rule (create {CA_MERGEABLE_FEATURE_CLAUSES_RULE}.make)
71 add_rule (create {CA_EMPTY_RESCUE_CLAUSE_RULE}.make)
72 add_rule (create {CA_INSPECT_NO_WHEN_RULE}.make)
73 add_rule (create {CA_EXPLICIT_REDUNDANT_INHERITANCE_RULE}.make)
74 add_rule (create {CA_UNDESIRABLE_COMMENT_CONTENT_RULE}.make (settings.preference_manager))
75 add_rule (create {CA_INHERIT_FROM_ANY_RULE}.make)
76 add_rule (create {CA_DOUBLE_NEGATION_RULE}.make)
77 add_rule (create {CA_EMPTY_LOOP_RULE}.make)
78 add_rule (create {CA_MISSING_CREATION_PROC_WITHOUT_ARGS_RULE}.make)
79 add_rule (create {CA_COMMENT_NOT_WELL_PHRASED_RULE}.make)
80 add_rule (create {CA_OBJECT_CREATION_WITHIN_LOOP_RULE}.make)
81 add_rule (create {CA_EMPTY_CREATION_PROC_RULE}.make)
82 add_rule (create {CA_VOID_CHECK_USING_IS_EQUAL_RULE}.make)
83 add_rule (create {CA_COMPARISON_OF_OBJECT_REFS_RULE}.make)
84 add_rule (create {CA_ATTRIBUTE_CAN_BE_CONSTANT_RULE}.make)
85 add_rule (create {CA_LOOP_INVARIANT_COMPUTATION_RULE}.make)
86 add_rule (create {CA_UNREACHABLE_CODE_RULE}.make)
87 add_rule (create {CA_OBJECT_TEST_FAILING_RULE}.make)
88 add_rule (create {CA_USELESS_CONTRACT_RULE}.make)
89 add_rule (create {CA_REAL_NAN_COMPARISON_RULE}.make)
90
91 settings.initialize_rule_settings (rules)
92
93 create classes_to_analyze.make
94 create rule_violations.make (100)
95 create completed_actions
96 create output_actions
97
98 create ignoredby.make (25)
99 create library_class.make (25)
100 create nonlibrary_class.make (25)
101 end
102
103 feature -- Analysis interface
104
105 add_completed_action (a_action: attached PROCEDURE [ANY, TUPLE [ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]]]])
106 -- Adds `a_action' to the list of procedures that will be
107 -- called when analysis has completed.
108 do
109 completed_actions.extend (a_action)
110 end
111
112 add_output_action (a_action: attached PROCEDURE [ANY, TUPLE [READABLE_STRING_GENERAL]])
113 -- Adds `a_action' to the procedures that are called for outputting status. The final results
114 -- (rule violations) are not given to these procedures.
115 do
116 output_actions.extend (a_action)
117 end
118
119 analyze
120 -- Analyze all the classes that have been added.
121 require
122 not is_running
123 local
124 l_rules_checker: CA_ALL_RULES_CHECKER
125 l_task: CA_RULE_CHECKING_TASK
126 l_rules_to_check: LINKED_LIST [CA_RULE]
127 do
128 is_running := True
129
130 create l_rules_checker.make
131 create l_rules_to_check.make
132 across rules as l_rules loop
133 l_rules.item.clear_violations
134 if is_rule_checkable (l_rules.item) then
135 l_rules_to_check.extend (l_rules.item)
136 -- Here we only prepare standard rules. The rule checking task will iterate again
137 -- through the rules and run the analysis on the enabled rules.
138 if attached {CA_STANDARD_RULE} l_rules.item as l_std_rule then
139 l_std_rule.prepare_checking (l_rules_checker)
140 end
141 end
142 end
143
144 create l_task.make (l_rules_checker, l_rules_to_check, classes_to_analyze, agent analysis_completed)
145 l_task.set_output_actions (output_actions)
146 if attached rota as l_rota then
147 rota.run_task (l_task)
148 else
149 -- No ROTA task is available, we execute the task synchronously.
150 from
151
152 until
153 not l_task.has_next_step
154 loop
155 l_task.step
156 end
157 end
158 end
159
160 is_rule_checkable (a_rule: attached CA_RULE): BOOLEAN
161 -- Will `a_rule' be checked based on the current preferences and based on the current
162 -- checking scope?
163 do
164 Result := a_rule.is_enabled.value
165 and then (system_wide_check or else (not a_rule.is_system_wide))
166 and then is_severity_enabled (a_rule.severity)
167 end
168
169 clear_classes_to_analyze
170 -- Removes all classes that have been added to the list of classes
171 -- to analyze.
172 do
173 classes_to_analyze.wipe_out
174 end
175
176 add_whole_system
177 -- Adds all the classes that are part of the current system. Classes of referenced libraries
178 -- will not be added.
179 do
180 across
181 eiffel_universe.groups as l_groups
182 loop
183 -- Only load top-level clusters, as the others will be loaded recursively afterwards.
184 if attached {CLUSTER_I} l_groups.item as l_cluster and then l_cluster.parent_cluster = Void then
185 add_cluster (l_cluster)
186 end
187 end
188
189 system_wide_check := True
190 end
191
192 add_cluster (a_cluster: attached CLUSTER_I)
193 -- Add all classes of cluster `a_cluster'.
194 do
195 system_wide_check := False
196
197 if a_cluster.classes /= Void then
198 across a_cluster.classes as ic loop
199 add_class (ic.item)
200 end
201 end
202
203 if a_cluster.sub_clusters /= Void then
204 across a_cluster.sub_clusters as ic loop
205 add_cluster (ic.item)
206 end
207 end
208 end
209
210 add_group (a_group: attached CONF_GROUP)
211 -- Add all classes of the configuration group `a_group'.
212 require
213 a_group_not_void: a_group /= Void
214 do
215 if a_group.classes /= Void then
216 across a_group.classes as ic loop
217 add_class (ic.item)
218 end
219 end
220 end
221
222 add_classes (a_classes: attached ITERABLE [attached CONF_CLASS])
223 -- Add the classes `a_classes'.
224 do
225 system_wide_check := False
226
227 across a_classes as l_classes loop
228 add_class (l_classes.item)
229 end
230 end
231
232 add_class (a_class: attached CONF_CLASS)
233 -- Adds class `a_class'.
234 do
235 system_wide_check := False
236
237 if attached {EIFFEL_CLASS_I} a_class as l_eiffel_class
238 and then attached l_eiffel_class.compiled_class as l_compiled
239 then
240 classes_to_analyze.extend (l_compiled)
241
242 extract_indexes (l_compiled)
243 else
244 output_actions.call ([ca_messages.class_skipped (a_class.name)])
245 end
246 end
247
248
249 force_preferences (a_preferences: LIST [TUPLE [rule_id: READABLE_STRING_GENERAL; preference_name: STRING; preference_value: READABLE_STRING_GENERAL]])
250 -- Forcefully set the preferences in `a_preferences' to the specified values,
251 -- overwriting the current ones.
252 local
253 l_full_preference_name: STRING
254 l_preference: PREFERENCE
255 do
256 -- Disable all rules.
257 across rules as ic loop
258 ic.item.is_enabled.set_value (False)
259 end
260
261 across a_preferences as ic loop
262 if rules.has_key (ic.item.rule_id) then
263 l_full_preference_name := rules.found_item.full_preference_name (ic.item.preference_name)
264 l_preference := preferences.get_preference (l_full_preference_name)
265
266 if attached l_preference then
267 l_preference.set_value_from_string (ic.item.preference_value)
268 else
269 output_actions.call ([ca_messages.preference_not_found (l_full_preference_name)])
270 end
271
272 else
273 output_actions.call ([ca_messages.rule_not_found (ic.item.rule_id)])
274 end
275 end
276 end
277
278
279 feature -- Properties
280
281 is_running: BOOLEAN
282 -- Is code analysis running?
283
284 rules: STRING_TABLE [CA_RULE]
285 -- Table containing the rules that will be used for analysis. Rules are indexed by ID.
286
287 add_rule (a_rule: CA_RULE)
288 -- Adds `a_rule' to the rules list.
289 require
290 not_added_yet: not rules.has (a_rule.id)
291 do
292 rules.extend (a_rule, a_rule.id)
293 ensure
294 added: rules.has (a_rule.id)
295 end
296
297 rule_violations: detachable HASH_TABLE [SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION], CLASS_C]
298 -- All found violations from the last analysis.
299
300 settings: CA_SETTINGS
301 -- The settings manager for Code Analysis.
302
303 preferences: PREFERENCES
304 -- Code Analysis preferences.
305 do Result := settings.preferences end
306
307 class_list: ITERABLE [CLASS_C]
308 -- List of classes that have been added.
309 do Result := classes_to_analyze end
310
311 feature {NONE} -- Implementation
312
313 csv_file_name: STRING = "last_analysis_result.csv"
314
315 csv_header: STRING = "Severity;Class;Location;Title;Description;Rule ID;Severity Score"
316
317 analysis_completed (a_exceptions: detachable ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]])
318 -- Will be called when the analysis task has finished. `a_exceptions'
319 -- contains a list of exception that occurred during analysis.
320 local
321 l_csv_writer: CA_CSV_WRITER
322 do
323 create l_csv_writer.make (eiffel_project.project_location.target_path.extended (csv_file_name), csv_header)
324
325 across rules as l_rules loop
326 across l_rules.item.violations as l_v loop
327 -- Check the ignore list.
328 if is_violation_valid (l_v.item) then
329 -- Make sure a list for this class exists in the hash table:
330 rule_violations.put (create {SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION]}.make, l_v.item.affected_class)
331 -- Add the violation.
332 rule_violations.at (l_v.item.affected_class).extend (l_v.item)
333 -- Log it.
334 l_csv_writer.add_line (l_v.item.csv_line)
335 end
336 end
337 end
338
339 l_csv_writer.close_file
340
341 clear_classes_to_analyze
342
343 is_running := False
344 completed_actions.call ([a_exceptions])
345 completed_actions.wipe_out
346 end
347
348 is_violation_valid (a_viol: attached CA_RULE_VIOLATION): BOOLEAN
349 -- Is the violation `a_viol' valid under the current settings
350 -- such as the rule ignore list of a class, or the library or
351 -- non-library status of a class?
352 local
353 l_affected_class: CLASS_C
354 l_rule: CA_RULE
355 do
356 l_affected_class := a_viol.affected_class
357 l_rule := a_viol.rule
358
359 Result := True
360
361 if ignoredby.has (l_affected_class)
362 and then (ignoredby.at (l_affected_class)).has (l_rule.id) then
363 Result := False
364 end
365
366 if (not l_rule.checks_library_classes) and then library_class.at (l_affected_class) then
367 Result := False
368 end
369
370 if (not l_rule.checks_nonlibrary_classes) and then nonlibrary_class.at (l_affected_class) then
371 Result := False
372 end
373 end
374
375 classes_to_analyze: LINKED_SET [CLASS_C]
376 -- List of classes that shall be analyzed.
377
378 system_wide_check: BOOLEAN
379 -- Shall the whole system be analyzed?
380
381 completed_actions: ACTION_SEQUENCE [TUPLE [ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]]]]
382 -- List of procedures to call when analysis has completed.
383
384 frozen rota: detachable ROTA_S
385 -- Accesses the rota service.
386 local
387 l_service_consumer: SERVICE_CONSUMER [ROTA_S]
388 do
389 create l_service_consumer
390 if attached l_service_consumer.service as l_service and then l_service.is_interface_usable then
391 Result := l_service
392 end
393 end
394
395 is_severity_enabled (a_severity: attached CA_RULE_SEVERITY): BOOLEAN
396 do
397 Result := (attached {CA_HINT} a_severity and settings.are_hints_enabled.value)
398 or else (attached {CA_SUGGESTION} a_severity and settings.are_suggestions_enabled.value)
399 or else (attached {CA_WARNING} a_severity and settings.are_warnings_enabled.value)
400 or else (attached {CA_ERROR} a_severity and settings.are_errors_enabled.value)
401 end
402
403 output_actions: ACTION_SEQUENCE [TUPLE [READABLE_STRING_GENERAL]]
404 -- Will be called whenever there is a message to output.
405
406 feature {NONE} -- Class-wide Options (From Indexing Clauses)
407
408 extract_indexes (a_class: attached CLASS_C)
409 -- Extracts options from the indexing clause of class `a_class'.
410 local
411 l_ast: CLASS_AS
412 l_ignoredby: LINKED_LIST [STRING_32]
413 do
414 create l_ignoredby.make
415 l_ignoredby.compare_objects -- We want to compare the actual strings.
416 -- Reset the class flags.
417 library_class.force (False, a_class)
418 nonlibrary_class.force (False, a_class)
419 l_ast := a_class.ast
420
421 if attached l_ast.internal_top_indexes as l_top then
422 search_indexing_tags (l_top, a_class, l_ignoredby)
423 end
424 if attached l_ast.internal_bottom_indexes as l_bottom then
425 search_indexing_tags (l_bottom, a_class, l_ignoredby)
426 end
427
428 ignoredby.force (l_ignoredby, a_class)
429 end
430
431 search_indexing_tags (a_clause: attached INDEXING_CLAUSE_AS; a_class: attached CLASS_C; a_ignoredby: attached LINKED_LIST [STRING_32])
432 -- Searches `a_clause' for settings relevant to code analysis.
433 local
434 l_item: STRING_32
435 do
436 across a_clause as ic loop
437 if attached ic.item.tag as l_tag then
438 if l_tag.name_32.same_string_general ("ca_ignoredby") then
439 -- Class wants to ignore certain rules.
440 across ic.item.index_list as l_list loop
441 l_item := l_list.item.string_value_32
442 l_item.prune_all ('%"')
443 a_ignoredby.extend (l_item)
444 end
445 elseif l_tag.name_32.is_equal ("ca_library") then
446 -- Class has information on whether it is a library class.
447 if not ic.item.index_list.is_empty then
448 l_item := ic.item.index_list.first.string_value_32
449 l_item.to_lower
450 l_item.prune_all ('%"')
451 if l_item.is_equal ("true") then
452 library_class.force (True, a_class)
453 elseif l_item.is_equal ("false") then
454 nonlibrary_class.force (True, a_class)
455 end
456 end
457 end
458 end
459 end
460 end
461
462 ignoredby: HASH_TABLE [LINKED_LIST [STRING_32], CLASS_C]
463 -- Maps classes to lists of rules (rule IDs) the class wants to be ignored by.
464
465 library_class, nonlibrary_class: HASH_TABLE [BOOLEAN, CLASS_C]
466 -- Stores classes that are marked as library or non-library classes.
467
468 invariant
469 -- law_of_non_contradiction: one class must not be both a library_class and a nonlibrary_class
470
471 end

Properties

Name Value
svn:eol-style native
svn:keywords Author Date ID Revision

  ViewVC Help
Powered by ViewVC 1.1.23